MS-Office-Forum
Google
   

Zurück   MS-Office-Forum > Microsoft Office > Microsoft Excel
Registrieren Forum Hilfe Alle Foren als gelesen markieren

Banner und Co.

Antworten
Ads Der Renner, 11 Entwicklertools für Access, Tipps & Trick und offene Datenbanken zum einzigartigen Preis.
Themen-Optionen Ansicht
Alt 08.01.2017, 19:00   #1
Sonnenlicht
MOF User
MOF User
Standard VBA - Gebäude Nr. suchen und Werte in Datenüberprüfung schreiben

Hi,

ich habe folgendes Problem:

Ich habe in einem Tabellenblatt "Gebäude" Gebäudedaten, diese Gebäudedaten sollen als Eingabemeldung entsprechend der richtigen Gebäude Nr. in einem 2.
Tabellenblatt "Strom" bei Auswahl/Klick der Gebäude Nr. angezeigt werden.

Eine Bsp. Datei ist angehängt. Hier Habe ich im Tabellenbaltt "Strom" es examplarisch für die 1. Gebäude Nr. mal gemacht. In eckigen Klammern habe ich geschreiben nach welcher Reihenfolge ich die Daten in der Eigabemeldung haben möchte.

Dieses System würde ich gerne auch noch für weitere Tabellenblätter verwenden z.B. Tabellenblatt "Wasser" usw. und es müsste über die gesamte Spalte der Gebäude Nr. laufen, da die Tabellen erweiter werden.

Eine VBA Lösung wäre mir auch rechtens.

Vielen vielen Dank im Voraus für eure Unterstüzung!
Für andere Ideen bin ich offen

Gruß Sonnenlicht
Angehängte Dateien
Dateityp: xlsx Gebüde Nr. suchen und daten in Datenüberprüfung schreiben.xlsx (11,7 KB, 15x aufgerufen)

Geändert von Sonnenlicht (08.01.2017 um 19:03 Uhr).
Sonnenlicht ist offline  
verlinken auf Del.icio.us Diese Seite zu Mister Wong hinzufügen
Antworten Auf Beitrag antworten
Alt 08.01.2017, 19:03   #2
Klaus-Dieter
MOF Profi
MOF Profi
Standard

Hallo,

Zitat:

Eine Bsp. Datei ist angehängt.

sehe ich nicht.

__________________


Viele Grüße Klaus-Dieter

Klaus-Dieter's Excel und VBA Seite
Klaus-Dieter ist offline  
verlinken auf Del.icio.us Diese Seite zu Mister Wong hinzufügen
Antworten Auf Beitrag antworten
Alt 08.01.2017, 19:18   #3
Beverly
MOF Guru
MOF Guru
Standard

Hi,

erstelle doch einfach für jede Zelle einen Kommentar mit den gewünschten Angaben.


GrußformelBeverly's Excel - Inn

__________________

Möchtest du dich für die Hilfe bei der Lösung deines Problems bedanken? Das kannst du ganz einfach durch die Bewertung eines Beitrags (Schalter unten links).
Beverly ist offline  
verlinken auf Del.icio.us Diese Seite zu Mister Wong hinzufügen
Antworten Auf Beitrag antworten
Alt 08.01.2017, 20:12   #4
Beverly
MOF Guru
MOF Guru
Standard

Hi,

hier mal 2 Möglichkeiten:

1. als Kommentar

Code:

Sub KommentareErstellen()
    Dim rngZelle As Range
    Dim intSpalte As Integer
    Dim strText As String
    Dim arrSpalten()
    arrSpalten = Array(2, 5, 7, 4, 3)
    With ActiveSheet.ListObjects(1).DataBodyRange.Columns(1)
        For Each rngZelle In .Cells
            With Worksheets("Gebäude")
                For intSpalte = 0 To 4
                    If intSpalte = 2 Then
                        strText = strText & vbLf & .Cells(rngZelle.Row, arrSpalten(intSpalte)) & " " & .Cells(rngZelle.Row, arrSpalten(intSpalte) - 1)
                    Else
                        strText = strText & vbLf & .Cells(rngZelle.Row, arrSpalten(intSpalte))
                    End If
                Next intSpalte
            End With
            If Not rngZelle Is Nothing Then
                rngZelle.Comment.Text Mid(strText, 2)
            Else
                rngZelle.AddComment Mid(strText, 2)
            End If
            rngZelle.Comment.Shape.DrawingObject.AutoSize = True
            strText = ""
        Next rngZelle
    End With
End Sub

und 2. als Eingabemeldung

Code:

Sub EingabemeldungErstellen()
    Dim rngZelle As Range
    Dim intSpalte As Integer
    Dim strText As String
    Dim arrSpalten()
    arrSpalten = Array(2, 5, 7, 4, 3)
    With ActiveSheet.ListObjects(1).DataBodyRange.Columns(1)
        For Each rngZelle In .Cells
            With Worksheets("Gebäude")
                For intSpalte = 0 To 4
                    If intSpalte = 2 Then
                        strText = strText & vbLf & .Cells(rngZelle.Row, arrSpalten(intSpalte)) & " " & .Cells(rngZelle.Row, arrSpalten(intSpalte) - 1)
                    Else
                        strText = strText & vbLf & .Cells(rngZelle.Row, arrSpalten(intSpalte))
                    End If
                Next intSpalte
            End With
            With rngZelle.Validation
                .Delete
                .Add Type:=xlValidateInputOnly, AlertStyle:=xlValidAlertStop, Operator:=xlBetween
                .InputTitle = "Information"
                .InputMessage = Mid(strText, 2)
                .ShowInput = True
            End With
            strText = ""
        Next rngZelle
    End With
End Sub


GrußformelBeverly's Excel - Inn

__________________

Möchtest du dich für die Hilfe bei der Lösung deines Problems bedanken? Das kannst du ganz einfach durch die Bewertung eines Beitrags (Schalter unten links).
Beverly ist offline  
verlinken auf Del.icio.us Diese Seite zu Mister Wong hinzufügen
Antworten Auf Beitrag antworten
Alt 08.01.2017, 21:01   #5
Sonnenlicht
Threadstarter Threadstarter
MOF User
MOF User
Standard

Hi Beverly,

Danke! Ich habe mich für die Eingabemeldung-Variante entschieden. Nun ist es so, dass ich wenn ich im Tabellenblatt "Gebäude" eine Gebäude Nr. hinzufüge und diese auch in dem Tabellenblatt "Strom" hinzufüge, die Eingabemeldung nicht automatisch erstellt wird. Da müsste ich doch im VBA "Strom" mit Private Sub Worksheet_Activate() arbeiten oder?

Und nun habe ich noch weitere Tabellenblätter, die wie das Tabellenblatt "Strom" aufgebaut sind z.B. Tabellenblatt Wasser, Wärme usw. also sehr gut wäre es, wenn ich sagen könnte für welche Tabellenblätter die Eingabemeldung gelten soll. Da müsste ich doch an dieser Stelle:
Code:

With ActiveSheet.ListObjects(1).DataBodyRange.Columns(1)
ansetzen oder?

Vielen lieben Dank im Voraus Gruß Sonnenlicht
Sonnenlicht ist offline  
verlinken auf Del.icio.us Diese Seite zu Mister Wong hinzufügen
Antworten Auf Beitrag antworten
Alt 08.01.2017, 21:52   #6
Sonnenlicht
Threadstarter Threadstarter
MOF User
MOF User
Standard

Hi,

Bei dem Code für dem Kommentar wird mir immer der Fehler Objektvariable oder With-Blockvariable nicht festgelegt angezeigt :
Code:

rngZelle.Comment.Text Mid(strText, 2)
und
Code:

rngZelle.Comment.Shape.DrawingObject.AutoSize = True
Ist dieses für die Autogrößen Anpassung des Kommentars an den Text?

Ich habe mal geschaut, der Nachteil bei der Eingabemeldung ist, dass der Kommentar nicht an der Text größe angepasst werden kann oder ist dieses irgendwiee doch möglich?

Gruß Sonnenlicht
Sonnenlicht ist offline  
verlinken auf Del.icio.us Diese Seite zu Mister Wong hinzufügen
Antworten Auf Beitrag antworten
Alt 09.01.2017, 08:52   #7
Beverly
MOF Guru
MOF Guru
Standard

Hi,

wenn du den Kommentar oder die Eingabemeldung bei Eintrag erstellen willst, musst du das Change-Ereignis des Tabellenblattes verwenden.

Für Kommentar:

Code:

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim intSpalte As Integer
    Dim strText As String
    Dim arrSpalten()
    arrSpalten = Array(2, 5, 7, 4, 3)
    If Not Intersect(Target, ActiveSheet.ListObjects(1).DataBodyRange.Columns(1)) Is Nothing Then
        If Target.Count = 1 Then
            With ActiveSheet.ListObjects(1).DataBodyRange.Columns(1)
                With Worksheets("Gebäude")
                    For intSpalte = 0 To 4
                        If intSpalte = 2 Then
                            strText = strText & vbLf & .Cells(Target.Row, arrSpalten(intSpalte)) & " " & .Cells(Target.Row, arrSpalten(intSpalte) - 1)
                        Else
                            strText = strText & vbLf & .Cells(Target.Row, arrSpalten(intSpalte))
                        End If
                    Next intSpalte
                End With
                If Not Target.Comment Is Nothing Then
                    Target.Comment.Text Mid(strText, 2)
                Else
                    Target.AddComment Mid(strText, 2)
                End If
                Target.Comment.Shape.DrawingObject.AutoSize = True
                strText = ""
            End With
        End If
    End If
End Sub
Für Eingabemeldung:

Code:

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim intSpalte As Integer
    Dim strText As String
    Dim arrSpalten()
    arrSpalten = Array(2, 5, 7, 4, 3)
    If Not Intersect(Target, ActiveSheet.ListObjects(1).DataBodyRange.Columns(1)) Is Nothing Then
        If Target.Count = 1 Then
            With Worksheets("Gebäude")
                For intSpalte = 0 To 4
                    If intSpalte = 2 Then
                        strText = strText & vbLf & .Cells(Target.Row, arrSpalten(intSpalte)) & " " & .Cells(Target.Row, arrSpalten(intSpalte) - 1)
                    Else
                        strText = strText & vbLf & .Cells(Target.Row, arrSpalten(intSpalte))
                    End If
                Next intSpalte
            End With
            With ActiveSheet.ListObjects(1).DataBodyRange.Columns(1)
                With Target.Validation
                    .Delete
                    .Add Type:=xlValidateInputOnly, AlertStyle:=xlValidAlertStop, Operator:=xlBetween
                    .InputTitle = "Information"
                    .InputMessage = Mid(strText, 2)
                    .ShowInput = True
                End With
            End With
        End If
    End If
End Sub

Der Fehler im Code für Kommentare trat deshalb auf, weil in dieser Zeile der rot markierte Teil fehlte:

Code:

If Not rngZelle.Comment Is Nothing Then
Weshalb der Teil fehlt, kann ich jetzt nicht mehr nachvollziehen, weil ich den Code eigentlich getestet hatte und kein Fehler auftrat.


Zur Frage der Größe der Anzeige: die Eingabemeldung hat offensichtlich eine Maximalbreite, wogegen der Kommentar diese Beschränkung nicht aufweist.


GrußformelBeverly's Excel - Inn

__________________

Möchtest du dich für die Hilfe bei der Lösung deines Problems bedanken? Das kannst du ganz einfach durch die Bewertung eines Beitrags (Schalter unten links).
Beverly ist offline  
verlinken auf Del.icio.us Diese Seite zu Mister Wong hinzufügen
Antworten Auf Beitrag antworten
Alt 09.01.2017, 14:57   #8
Sonnenlicht
Threadstarter Threadstarter
MOF User
MOF User
Standard

Hi,

ich wollte jetzt den Codedes Kommentars in das gewünschte Tabellenblatt einfügen, für welches es geltn soll.

Leider habe ich dort schon Code stehen :
Code:

Private Sub Worksheet_Change(ByVal Target As Range)
    If Target.Row > Range("SN_Wärme_Aktuell[#All]").Cells(1).Row And InStr(1, Cells(Range("SN_Wärme_Aktuell[#All]").Cells(1).Row, Target.Column), "X") > 0 Then
        If Target <> "" And Target.Column = Range("SN_Wärme_Aktuell[#All]").Columns.Count Then
           neuerKopf1 Range("SN_Wärme_Aktuell[#All]").Columns.Count, Range("SN_Wärme_Aktuell[#All]").Cells(1).Row
        End If
    End If
End Sub
somit wird mir angezeigt, dass
Code:

Private Sub Worksheet_Change(ByVal Target As Range)
existiert. Nun hatte ich gedacht, dass ich deinen Code einfach unter den bisherigen Code tun kann, aber leider funktioniert es nicht

Vielen Dank in Voraus Gruß Sonnenlicht
Sonnenlicht ist offline  
verlinken auf Del.icio.us Diese Seite zu Mister Wong hinzufügen
Antworten Auf Beitrag antworten
Alt 09.01.2017, 16:06   #9
Beverly
MOF Guru
MOF Guru
Standard

Hi,

wenn tatsächlich beides im selben Tabellenblatt stattfinden soll, dann mittels ElseIf (ungetestet):


Code:

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim intSpalte As Integer
    Dim strText As String
    Dim arrSpalten()
    arrSpalten = Array(2, 5, 7, 4, 3)
    If Target.Row > Range("SN_Wärme_Aktuell[#All]").Cells(1).Row And InStr(1, Cells(Range("SN_Wärme_Aktuell[#All]").Cells(1).Row, Target.Column), "X") > 0 Then
        If Target <> "" And Target.Column = Range("SN_Wärme_Aktuell[#All]").Columns.Count Then
           neuerKopf1 Range("SN_Wärme_Aktuell[#All]").Columns.Count, Range("SN_Wärme_Aktuell[#All]").Cells(1).Row
        End If
    ElseIf Not Intersect(Target, ActiveSheet.ListObjects(1).DataBodyRange.Columns(1)) Is Nothing Then
        If Target.Count = 1 Then
            With ActiveSheet.ListObjects(1).DataBodyRange.Columns(1)
                With Worksheets("Gebäude")
                    For intSpalte = 0 To 4
                        If intSpalte = 2 Then
                            strText = strText & vbLf & .Cells(Target.Row, arrSpalten(intSpalte)) & " " & .Cells(Target.Row, arrSpalten(intSpalte) - 1)
                        Else
                            strText = strText & vbLf & .Cells(Target.Row, arrSpalten(intSpalte))
                        End If
                    Next intSpalte
                End With
                If Not Target.Comment Is Nothing Then
                    Target.Comment.Text Mid(strText, 2)
                Else
                    Target.AddComment Mid(strText, 2)
                End If
                Target.Comment.Shape.DrawingObject.AutoSize = True
                strText = ""
            End With
        End If
    End If
End Sub

GrußformelBeverly's Excel - Inn

__________________

Möchtest du dich für die Hilfe bei der Lösung deines Problems bedanken? Das kannst du ganz einfach durch die Bewertung eines Beitrags (Schalter unten links).
Beverly ist offline  
verlinken auf Del.icio.us Diese Seite zu Mister Wong hinzufügen
Antworten Auf Beitrag antworten
Alt 09.01.2017, 19:04   #10
Sonnenlicht
Threadstarter Threadstarter
MOF User
MOF User
Standard

Hi,

okay vielen lieben Dank funktioniert jetzt! Muss jedoch die Sub auch verwenden, da falls mal ein Gebäude gelöscht wird, sich das ganze nicht aktuallisiert.


Gruß Sonnenlicht
Sonnenlicht ist offline  
verlinken auf Del.icio.us Diese Seite zu Mister Wong hinzufügen
Antworten Auf Beitrag antworten
Alt 09.01.2017, 20:08   #11
Sonnenlicht
Threadstarter Threadstarter
MOF User
MOF User
Standard

Hi,

funktioniert leider doch nicht so wie gewünscht Da es leider vorkommt, dass es mehr Gebäude gbt, als Stromzähler kann die Zuordnung der Gebäude-Nr. nicht der Reihenfolge nach geschehen. Sprich es müss in die Strom Tabelle geschaut werden und dann nach der Gebäude-Nr. in der Gebäudetabelle und dort soll ggf. der erste gefundene Wert genommen werden.

Ist dieses möglich?


Gruß Sonnenlicht
Sonnenlicht ist offline  
verlinken auf Del.icio.us Diese Seite zu Mister Wong hinzufügen
Antworten Auf Beitrag antworten
Alt 09.01.2017, 20:32   #12
Beverly
MOF Guru
MOF Guru
Standard

Hi,

das geht nur wenn es ein eindeutiges Kriterium gibt, bei dir jedoch kommen die Kriterien mehrfach vor. Sicher kann man den 1. Wert finden, aber du hast ja z.B. für Nr. 9 zwei unterschiedliche Straßenbezeichnungen - in Zeile 11 wäre "Industriestr. 2" korrekt, für Zeile 12 jedoch würde "Industriestraße 2" ausgegeben, obwohl dort "Industriestraße 1" stehen müsste - somit wäre ja der eigentliche Zweck der Information völlig verfehlt.


GrußformelBeverly's Excel - Inn

__________________

Möchtest du dich für die Hilfe bei der Lösung deines Problems bedanken? Das kannst du ganz einfach durch die Bewertung eines Beitrags (Schalter unten links).
Beverly ist offline  
verlinken auf Del.icio.us Diese Seite zu Mister Wong hinzufügen
Antworten Auf Beitrag antworten
Alt 09.01.2017, 21:48   #13
Sonnenlicht
Threadstarter Threadstarter
MOF User
MOF User
Standard

Hi,

ja blödes Bsp. Ich habe nochmal alle Daten angeschaut, also die Gebäude befinden sich immer in der selben Straße und haben die selbe Hausnummer (ab und an wäre es z.B. Hausnummer 8 und 8a). Mir reicht dieser "fast" richtige Wert, da die nachfolgenden gleichen Gebäude-Nr. zugeordnet werden können anhand der Strom-Rechung (bzw. Steckt hinter der Auflistung der Gebäude-Nr. eine Logische Reihenfolge, 1 auftauchende Gebäude-Nr. einer Gruppe ist immmer das Hauptgebäude usw.) So das im Grunde genommen nur erkennbar sein muss, welche Gebäude-Nr. welches Gebäude überhaupt ist. Einziges eindeutige Kriterium wäre zusätzlich die Nutzung in Betracht zu ziehen, diese ist immer unterschiedlich in jeder Gebäude-Gruppe. Also z.B. bei Gebäude-Nr. 9 kommt niemals die gleiche Nutzung vor. Aber dieses glaube ich ist niemals umsetzbar.

Gruß Sonnenlicht
Sonnenlicht ist offline  
verlinken auf Del.icio.us Diese Seite zu Mister Wong hinzufügen
Antworten Auf Beitrag antworten
Alt 10.01.2017, 09:14   #14
Beverly
MOF Guru
MOF Guru
Standard

Hi,

als eindeutiges Kriterium meinte ich so etwas wie eine fortlaufende Nummer in einer zusätzlichen Spalte, denn auch die Nutzung kann nicht als eindeutiges Kriterium herangezogen werden, da z.B. für Gebäude 9 in beiden Fällen "Bauhof" steht. Außerdem gibt es in Tabelle2 keine Spalte mit der Nutzung, die man für einen Vergleich heranziehen könnte.

Code:

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim intSpalte As Integer
    Dim strText As String
    Dim arrSpalten()
    Dim lngZeile As Long
    Dim rngZelle As Range
    arrSpalten = Array(2, 5, 7, 4, 3)
    If Target.Row > Range("SN_Wärme_Aktuell[#All]").Cells(1).Row And InStr(1, Cells(Range("SN_Wärme_Aktuell[#All]").Cells(1).Row, Target.Column), "X") > 0 Then
        If Target <> "" And Target.Column = Range("SN_Wärme_Aktuell[#All]").Columns.Count Then
           neuerKopf1 Range("SN_Wärme_Aktuell[#All]").Columns.Count, Range("SN_Wärme_Aktuell[#All]").Cells(1).Row
        End If
    ElseIf Not Intersect(Target, ActiveSheet.ListObjects(1).DataBodyRange.Columns(1)) Is Nothing Then
        If Target.Count = 1 Then
            ' Eingabe ist <> ""
            If Target.Value <> "" Then
                With ActiveSheet.ListObjects(1).DataBodyRange.Columns(1)
                    With Worksheets("Gebäude")
                        ' eingetragene Gebäudenummer suchen
                        Set rngZelle = .Columns(1).Find(Target.Value, lookat:=xlWhole)
                        ' 1. Treffer wurde gefunden
                        If Not rngZelle Is Nothing Then
                            ' Kommentartext aus 1. gefundender Zeile zusammensetzen
                            For intSpalte = 0 To 4
                                If intSpalte = 2 Then
                                    strText = strText & vbLf & .Cells(rngZelle.Row, arrSpalten(intSpalte)) & " " & .Cells(rngZelle.Row, arrSpalten(intSpalte) - 1)
                                Else
                                    strText = strText & vbLf & .Cells(rngZelle.Row, arrSpalten(intSpalte))
                                End If
                            Next intSpalte
                        End If
                    End With
                    ' Gebäudenummer wurde gefunden deshalb ist Kommentartext <> ""
                    If strText <> "" Then
                        If Not Target.Comment Is Nothing Then
                            Target.Comment.Text Mid(strText, 2)
                        Else
                            Target.AddComment Mid(strText, 2)
                        End If
                        Target.Comment.Shape.DrawingObject.AutoSize = True
                        strText = ""
                    Else
                        MsgBox "Gebäudenummer nicht gefunden"
                    End If
                End With
            ' Zellinhalt wurde entfernt deshalb Kommentar löschen
            Else
                If Not Target.Comment Is Nothing Then Target.Comment.Delete
            End If
        End If
    End If
    Set rngZelle = Nothing
End Sub

Im Code ist auch berücksichtigt, dass eine Gebäudenummer gelöscht werden kann - in diesem Fall wird der Kommentar gelöscht. Falls eine Gebäudenummer nur geändert wird, wird der Kommentar automatisch ebenfalls geändert (dieser Teil war bereits im vorhergehenden Code enthalten).


GrußformelBeverly's Excel - Inn

__________________

Möchtest du dich für die Hilfe bei der Lösung deines Problems bedanken? Das kannst du ganz einfach durch die Bewertung eines Beitrags (Schalter unten links).
Beverly ist offline  
verlinken auf Del.icio.us Diese Seite zu Mister Wong hinzufügen
Antworten Auf Beitrag antworten
Alt 10.01.2017, 22:04   #15
Sonnenlicht
Threadstarter Threadstarter
MOF User
MOF User
Standard

Hi Beverly,

Danke klappt super! Ich habe mal geschaut, würde es ausreichen, wenn ich die neu hinzugekommenen Codezeilen aus dem Kommentar-Code in den Eingabemeldungs-Code einfüge, um das ganze als Eingabemeldung zu erhalten?
Da die Datei noch von anderen Mitarbeitern später bearbeitet werden soll und diese ggf. Kommentare an anderen Stellen hinzufügen (das habe ich so vorher überhaupt nicht bedacht Nun habe ich Angst, dass man nacher den Überblick verliert.

Gruß Sonnenlicht
Sonnenlicht ist offline  
verlinken auf Del.icio.us Diese Seite zu Mister Wong hinzufügen
Antworten Auf Beitrag antworten
Ads
Antworten


Aktive Benutzer in diesem Thema: 1 (Registrierte Benutzer: 0, Besucher: 1)
 
Themen-Optionen
Ansicht

Forumregeln
Es ist Ihnen nicht erlaubt, neue Themen zu verfassen.
Es ist Ihnen nicht erlaubt, auf Beiträge zu antworten.
Es ist Ihnen nicht erlaubt, Anhänge anzufügen.
Es ist Ihnen nicht erlaubt, Ihre Beiträge zu bearbeiten.

vB Code ist An.
Smileys sind An.
[IMG] Code ist An.
HTML-Code ist An.
Gehe zu


Alle Zeitangaben in WEZ +1. Es ist jetzt 14:48 Uhr.


Partner und Co.
Access-Paradies -Alles rund um die Datenbank Microsoft Access -Code -Programme-Tools -Tipps   Kostenlose Tipps & Tricks, Downloads und Programme   www.kulpa-online.com - Tipps - Tricks - Tutorials - Meinungen - Downloads uvm...   vb@rchiv · Willkommen in der Welt der VB Programmierung   Access-Garhammer - Hier finden Sie jede Menge Beispiel-Datenbanken zu Access und mehr ...   mcseboard.de   Die Top Seite für Excel-VBA-Makros uvm.

Powered by: vBulletin Version 3.6.2 (Deutsch)
Copyright ©2000 - 2017, Jelsoft Enterprises Ltd.

Copyright ©2000-2010 MS-Office-Forum. Alle Rechte vorbehalten.
Copyright ©Design: Manuela Kulpa ©Rechte: Günther Kramer
Eine Verwendung der Inhalte in anderen Publikationen, auch auszugsweise,
ist ohne ausdrückliche Zustimmung der Autoren nicht gestattet.
Beachten Sie bitte auch unsere Nutzungsbedingungen.